Si estás aprendiendo lógica de programación, estos ejercicios resueltos en PSeInt te pueden servir para practicar las estructuras más utilizadas: lectura de datos, condicionales, ciclos, acumuladores y operaciones matemáticas.
Todos los ejemplos están pensados para que puedas copiarlos en PSeInt, ejecutarlos, modificarlos y entender qué hace cada parte del algoritmo.
Índice de ejercicios
- Hola Mundo
- Mayor, menor o igual a 9
- Número par o impar
- Suma de dos números
- Suma de números pares entre 2 y 100
- Divisores de un número
- Promedio de calificaciones: aprobado o reprobado
- Repetir un nombre utilizando Mientras
- Suma del 1 al 50 utilizando Repetir
- Sumar o multiplicar tres números
- Determinar si un número es primo
- Suma de los dígitos de un número
1. Hola Mundo en PSeInt
Enunciado: escribir un programa que muestre el texto “¡Hola mundo!”.
Algoritmo hola_mundo
Escribir "Hola mundo"
FinAlgoritmo
Es el ejemplo más simple posible: permite comprobar cómo se define un algoritmo y cómo se muestra un mensaje en pantalla con Escribir.
2. Mayor, menor o igual a 9
Enunciado: ingresar un número e indicar si es mayor, menor o igual a 9.
Algoritmo MayoresIgualesMenoresA9
Escribir "Ingrese un numero"
Leer N
Si N = 9 Entonces
Escribir "El numero es igual a 9"
Sino
Si N > 9 Entonces
Escribir "El numero es mayor a 9"
Sino
Escribir "El numero es menor a 9"
FinSi
FinSi
FinAlgoritmo
Este ejercicio sirve para practicar decisiones mediante la estructura Si ... Entonces ... Sino.
3. Número par o impar en PSeInt
Enunciado: ingresar un número e indicar si es par o impar.
Algoritmo ParidadNumeros
Escribir "Ingrese un numero"
Leer nro
Si nro MOD 2 = 0 Entonces
Escribir "El numero es par"
Sino
Escribir "El numero es impar"
FinSi
FinAlgoritmo
La operación MOD devuelve el resto de una división. Si el resto de dividir un número por 2 es 0, el número es par. Ver el ejercicio de número par o impar explicado paso a paso.
4. Suma de dos números en PSeInt
Enunciado: ingresar dos números y mostrar el resultado de su suma.
Algoritmo SumaDosNumeros
Escribir "Ingrese el numero 1"
Leer Num1
Escribir "Ingrese el numero 2"
Leer Num2
resultado <- Num1 + Num2
Escribir "El resultado es: ", resultado
FinAlgoritmo
Primero se leen los dos valores, luego se almacena la suma en una tercera variable y finalmente se muestra el resultado.
5. Suma de números pares entre 2 y 100
Enunciado: sumar todos los números pares comprendidos entre 2 y 100.
Algoritmo SumaDePares
suma <- 0
nro <- 2
Mientras nro <= 100 Hacer
Si nro MOD 2 = 0 Entonces
suma <- suma + nro
FinSi
nro <- nro + 1
FinMientras
Escribir "La suma de los pares entre 2 y 100 es: ", suma
FinAlgoritmo
Aquí se utiliza suma como acumulador. En cada vuelta del ciclo se agrega el número actual solamente si es par.
6. Divisores de un número
Enunciado: ingresar un número y mostrar todos sus divisores.
Algoritmo DivisoresDeNumero
Escribir "Ingrese un numero positivo"
Leer num
div <- 1
Mientras div <= num Hacer
Si num MOD div = 0 Entonces
Escribir div
FinSi
div <- div + 1
FinMientras
FinAlgoritmo
Un número es divisor de otro cuando el resto de la división es cero. Por eso se prueba cada valor desde 1 hasta el número ingresado.
7. Promedio de calificaciones: aprobado o reprobado
Enunciado: ingresar tres calificaciones. El alumno aprueba si su promedio es mayor o igual a 4.
Algoritmo ApruebaReprueba
Escribir "Ingrese calificacion 1"
Leer cal1
Escribir "Ingrese calificacion 2"
Leer cal2
Escribir "Ingrese calificacion 3"
Leer cal3
promedio <- (cal1 + cal2 + cal3) / 3
Si promedio >= 4 Entonces
Escribir "Aprueba"
Sino
Escribir "Reprueba"
FinSi
Escribir "Promedio: ", promedio
FinAlgoritmo
El ejercicio combina operaciones aritméticas y una estructura condicional para tomar una decisión a partir del promedio.
8. Repetir un nombre utilizando Mientras
Enunciado: ingresar un nombre y una cantidad, y mostrar el nombre tantas veces como indique esa cantidad.
Algoritmo CantidadNombre
Escribir "Ingrese un nombre"
Leer nombre
Escribir "Ingrese una cantidad"
Leer cantidad
Mientras cantidad > 0 Hacer
Escribir nombre
cantidad <- cantidad - 1
FinMientras
FinAlgoritmo
En cada repetición se resta 1 a la cantidad hasta llegar a cero, momento en el que finaliza el ciclo.
9. Suma del 1 al 50 utilizando Repetir
Enunciado: sumar todos los números naturales comprendidos entre 1 y 50 utilizando Repetir.
Algoritmo SumaNumerosNaturales1a50
num <- 1
resultado <- 0
Repetir
resultado <- resultado + num
num <- num + 1
Hasta Que num > 50
Escribir "El resultado es: ", resultado
FinAlgoritmo
El acumulador comienza en cero y recibe el valor de cada número antes de incrementar el contador.
10. Sumar o multiplicar tres números
Enunciado: ingresar tres números. Si el primero es negativo, multiplicar los tres; de lo contrario, sumarlos.
Algoritmo TresNumeros
Escribir "Ingrese numero 1"
Leer num1
Escribir "Ingrese numero 2"
Leer num2
Escribir "Ingrese numero 3"
Leer num3
Si num1 < 0 Entonces
resultado <- num1 * num2 * num3
Sino
resultado <- num1 + num2 + num3
FinSi
Escribir "Resultado: ", resultado
FinAlgoritmo
La operación que se realiza depende del signo del primer número ingresado.
11. Número primo en PSeInt
Enunciado: determinar si un número entero ingresado es primo. Un número primo es un entero mayor que 1 que solamente tiene dos divisores positivos: 1 y él mismo.
Algoritmo NumeroPrimo
Escribir "Ingrese un numero entero"
Leer nro
Si nro <= 1 Entonces
Escribir "No es primo"
Sino
divisor <- 2
esPrimo <- Verdadero
Mientras divisor * divisor <= nro Y esPrimo Hacer
Si nro MOD divisor = 0 Entonces
esPrimo <- Falso
FinSi
divisor <- divisor + 1
FinMientras
Si esPrimo Entonces
Escribir "Es primo"
Sino
Escribir "No es primo"
FinSi
FinSi
FinAlgoritmo
No es necesario probar divisores hasta el propio número: alcanza con comprobar hasta su raíz cuadrada. Esto reduce considerablemente la cantidad de iteraciones. Ver el ejercicio de número primo explicado paso a paso.
12. Suma de los dígitos de un número
Enunciado: sumar todos los dígitos de un número entero positivo. Por ejemplo, para 123 el resultado debe ser 6.
Algoritmo SumaDigitos
Escribir "Ingrese un numero positivo"
Leer nro
resultado <- 0
Mientras nro <> 0 Hacer
resultado <- resultado + nro MOD 10
nro <- Trunc(nro / 10)
FinMientras
Escribir "El resultado es: ", resultado
FinAlgoritmo
MOD 10 permite obtener el último dígito, mientras que Trunc(nro / 10) elimina ese dígito para continuar con el siguiente. Ver el ejercicio de suma de dígitos explicado paso a paso.
¿Te sirvió este ejercicio? ☕
Si este contenido te ayudó, podés apoyar a Club Programador con el monto que quieras. Tu aporte nos ayuda a seguir publicando ejercicios resueltos y material gratuito.
Más ejercicios de PSeInt
Si querés continuar practicando, también podés consultar estos contenidos del sitio:
- Arreglos en PSeInt: vectores y ejercicios resueltos
- Número par o impar en PSeInt
- Número primo en PSeInt
- Suma de dígitos de un número en PSeInt
- Ejemplo de calculadora en PSeInt
- Introducción al intérprete PSeInt
- Trazas: cómo verificar algoritmos paso a paso
¿Cómo aprovechar estos ejercicios?
Una buena forma de aprender es ejecutar primero cada solución y después intentar modificarla: cambiar los límites de los ciclos, agregar validaciones, utilizar otros valores o resolver el mismo problema con una estructura diferente. El objetivo no es solamente copiar el código, sino entender la lógica que hay detrás de cada algoritmo.
Club Programador 
Elabore un programa que lea los datos de un cliente de un banco que solicita un crédito, número de la cuenta, nombre del cliente, ocupación, valor a prestar, y numero de cuotas. Calcular: Los interés, el valor total del préstamo y el valor de la cuota de cada mes.
– Los interés son iguales al valor del prestado multiplicado por el 1% por el número de cuotas
– El valor total es igual al valor a prestar más los intereses
– La cuota de cada mes es igual al valor total dividido el número de cuotas
Mostrar el valor total del préstamo y el valor de cada cuota.
Me gustaMe gusta
Elaborar un programa que me permita ingresar un número y me indique si este es positivo
o negativo.
Me gustaMe gusta
Crear un algoritmo que solicite al usuario un número entero
//positivo y realice las operaciones necesarias para mostrar como resultado
//la cantidad de cifras de dicho número. Ejemplo: si el número fuera 123 el resultado sería 3 cifras.
Me gustaMe gusta
1. elaborar un programa que Calcular el interés ganado por un capital invertido. (nombre, datos para calcular el interés capital)
Me gustaMe gusta
Realizar tres programas que permita determinar de un total de 5 usuarios cuantos de estos son mujeres y cuantos son hombres en pseint utilizando la extructura mientras
Me gustaMe gusta
Cree un algoritmo para ingresar un número cualquiera, escriba todos los múltiplos que hay en el intervalo cerrado [10, 30] de ese número
Me gustaMe gusta
Realizar un pseudocódigo que lea números enteros mientras el usuario no de un 0, si el
número es positivo almacénelo en un arreglo llamado POS y si el número es negativo
almacénelo en un arreglo llamado NEG, después desplegar los vectores, obtener la
media de ambos arreglos y ordenar el vector POS en forma ascendente y el vector NEG
en forma descendente, para concluir imprimir de nuevo ambos vectores.
Nota: La dimensión de los vectores que sea de 50.
Me gustaMe gusta
gracias, me ha ayudado muchísimo.
Me gustaLe gusta a 1 persona
gracias llevo 5 dias en clases de ing en sistemas y mañana tengo examen, estos ejercicios me han servido de mucho
Me gustaLe gusta a 1 persona
La empresa distribuye puertas, cofres, polveras y asientos. Elabora un programa que permita llevar el inventario actualizado acorde con la compra.
La empresa posee el siguiente inventario:
200 puertas, con un costo de $20,000 c/u.
150 cofres con un costo de $30,000 c/u.
10 polveras con un costo de $10,000 c/u.
8 asientos con un costo de 5000 c/u.
Imprimir el inventario actualizado en pantalla y solicitarle al cliente qué desea comprar. Una vez el cliente seleccione, se le solicita la cantidad y se imprime en pantalla el costo total de lo que se está comprando.
Al final, se debe mostrar el inventario actualizado y solo se sale del programa si el cliente escoge la opción de salir.
Me gustaMe gusta
Lo pudiste solucionar???
Me gustaMe gusta
Necesito ayuda
Un pseudocodigo donde se le pida al usuario que ingrese 2 números que solo permita que el usuario ingrese números no letras ni símbolos hare una exposición el 26/07 D: no es prioridad pero quisiera dar una buena exposición y mostrar que mi código cubre todas las variables posibles.
Me gustaMe gusta
REALIZAR UN PROGRAMA EN PSEINT QUE INGRESE UN NUMERO QUE DEBE DEBE ESTAR ENTRE 100 Y 200.
LUEGO CALCULAR EL CUBO DEL NÙMERO, Y A ESE RESULTADO MULTIPLICARLO POR 2.
Me gustaMe gusta